m_nvtx.f90

Go to the documentation of this file.

!>
!! @file
!! @brief Contains module m_nvtx
 
!> @brief NVIDIA NVTX profiling API bindings for GPU performance instrumentation
module m_nvtx
 
    use iso_c_binding
 
    implicit none
 
    integer, private :: col(7) = [int(z'0000ff00'), int(z'000000ff'), int(z'00ffff00'), int(z'00ff00ff'), int(z'0000ffff'), &
                            & int(z'00ff0000'), int(z'00ffffff')]
 
    character(len=256), private :: tempname
 
    type, bind(C) :: nvtxEventAttributes
        integer(c_int16_t) :: version = 1
        integer(c_int16_t) :: size = 48  !
        integer(c_int)     :: category = 0
        integer(c_int)     :: colortype = 1    !< NVTX_COLOR_ARGB = 1
        integer(c_int)     :: color
        integer(c_int)     :: payloadtype = 0  !< NVTX_PAYLOAD_UNKNOWN = 0
        integer(c_int)     :: reserved0
        integer(c_int64_t) :: payload          !< union uint,int,double
        integer(c_int)     :: messagetype = 1  !< NVTX_MESSAGE_TYPE_ASCII = 1
        type(c_ptr)        :: message          !< ascii char
    end type nvtxeventattributes
 
#if defined(MFC_GPU) && defined(__PGI)
    interface nvtxrangepush
        ! push range with custom label and standard color
        subroutine nvtxrangepusha(name) bind(C, name='nvtxRangePushA')
 
            use iso_c_binding
 
            character(kind=c_char, len=*), intent(in) :: name
 
        end subroutine nvtxrangepusha
        ! push range with custom label and custom color
        subroutine nvtxrangepushex(event) bind(C, name='nvtxRangePushEx')
 
            use iso_c_binding
 
            import :: nvtxeventattributes
            type(nvtxeventattributes), intent(in) :: event
 
        end subroutine nvtxrangepushex
    end interface nvtxrangepush
 
    interface nvtxrangepop
        subroutine nvtxrangepop() bind(C, name='nvtxRangePop')
 
        end subroutine nvtxrangepop
    end interface nvtxrangepop
#endif
 
contains
 
    !> Push a named NVTX range for GPU profiling, optionally with a color based on the given identifier.
    subroutine nvtxstartrange(name, id)
 
        character(kind=c_char, len=*), intent(in) :: name
        integer, intent(in), optional             :: id
        type(nvtxeventattributes)                 :: event
 
#if defined(MFC_GPU) && defined(__PGI)
        tempname = trim(name) // c_null_char
 
        if (.not. present(id)) then
            call nvtxrangepush(tempname)
        else
            event%color = col(mod(id, 7) + 1)
            event%message = c_loc(tempname)
            call nvtxrangepushex(event)
        end if
#endif
 
    end subroutine nvtxstartrange
 
    !> Pop the current NVTX range to end the GPU profiling region.
    subroutine nvtxendrange
 
#if defined(MFC_GPU) && defined(__PGI)
        call nvtxrangepop
#endif
 
    end subroutine nvtxendrange
 
end module m_nvtx